etc/conf/maildirs.m4

dnl or(either, otherwise)
define(`or', `ifelse(`$1', `', `$2', `$1')')

dnl q(text)
define(`q', `patsubst(`$1', `[.]', `\\\&')')

dnl join(delim, elems*)
define(`join', `ifelse(
	`$#', `0', `',
	`$#', `1', `',
	`$#', `2', `$2',
	``$2$1'join(`$1', shift(shift($@)))')')

dnl md*(mbox, rule, addr)
define(`md', `indir(`md_'md_target, $@)')

dnl muttrc
define(`md_muttrc_mboxes', `mailboxes +$1')
define(`md_muttrc_subscr', `ifelse(`$3', `', `', `subscribe $3')')

dnl procmailrc
define(`md_procmailrc', `
:0
* ^$2
deliver(`$1')

')

dnl ml(addr, mbox, id, fix, rule)
define(`ml', `md(
	or(`$2', `substr(`$1', 0, index(`$1', `@'))'),
	ml_rule(or(`$3', `ifelse(
	  `$4', `ecartis', `substr(`$1', 0, index(`$1', `@'))',
	  `translit(`$1', `@', `.')')'), `$1', `$4', `$5'),
	`$1')')

dnl ml_rule(id, addr, fix, rule)
define(`ml_rule', `ifelse(
		`$3', `to', `TO_`'q($2)',
		`$3', `ezmlm', `Mailing-List:.* q(substr(`$2', 0,
			index(`$2', `@'))-help`'substr(`$2', index(`$2', `@')));',
		`$3', `ecartis', `X-list: q($1)$',
		`$4', `', `List-Id:.*[ <]q($1)',
		`$4')')

dnl Mailing Lists
ml(`swpat@ffii.org', `ffii-swpat')
ml(`at-parl@ffii.org', `ffii-at-parl')
ml(`swpat@mond.at', `mond-swpat')
ml(`soekris-tech@lists.soekris.com')
ml(`www-math@w3.org')
ml(`geo-discuss@lists.okfn.org')
ml(`geowanking@geowanking.org',, `geowanking_geowanking.org.geowanking.org')
ml(`info-gplv3@gplv3.fsf.org', `gplv3',, `to')
ml(`(european-gi-policy|egip)@jrc.it', `egip',, `to')
ml(`cryopid-devel@lists.berlios.de')
ml(`lojban-beginners@lojban.org',,, `ecartis')
ml(`lojban-list@lojban.org',,, `ecartis')
ml(`talk-de@openstreetmap.org')
ml(`talk-fr@openstreetmap.org')
ml(`josm-dev@openstreetmap.org')
ml(`legal-talk@openstreetmap.org')
ml(`tahoe-dev@allmydata.org')
ml(`ceph-devel@lists.sourceforge.net')
ml(`fonc@vpri.org')

dnl Mailman reminders
md(`reminders', `From: mailman-owner@
* ^Subject:.* list memberships reminder$')

dnl Bugzillas
define(`bz', `md(`bugs-$1', `$2')')
bz(`debian', `From.*<owner@bugs.debian.org>')
bz(`gcc', `Reply-To: gcc-bugzilla@gcc.gnu.org')
bz(`gentoo', `From: bugzilla-daemon@gentoo.org')
bz(`kde', `X-Bugzilla-URL: http://bugs.kde.org/')
bz(`remotesensing', `From: bugzilla-daemon@bugzilla.remotesensing.org')
bz(`sablevm', `From: bugs-owner@sablevm.org')
bz(`berlios', `From: noreply@berlios.de')
bz(`gnome', `From: bugzilla-daemon@bugzilla.gnome.org')

dnl Misc
md(`osm', `Subject:.*\[OpenStreetMap\] GPX Import success')
md(`sourceforge', `From:.*noreply@sourceforge\.net')

dnl System
md(`system', `From: root@gabrielebner\.at \(Cron Daemon\)$')
md(`snort', `Subject: \[SNORT\]')

dnl GMane
md(`gmane', `From:.*auth.gmane\.org')

dnl Service providers
md(`ums', `From:.*ums@a1\.net')
md(`nit', `From:.*kundensupport@nit\.at')

dnl Newsletters
md(`ffii', `From:.*ffii.org|TO_.*ffii.org')
md(`diepresse', `From:.*newsletter@diepresse.com')
md(`geocaching', `From:.*<noreply@geocaching.com>')

md(`werbung', `From:.*('join(`|',
	`newsletter',
	`newslist',
	`newsteam',
	`mailing',
	`palmsource',
	`palmgear',
	`palmone',
	`ebook.nl',
	`webmaster@sony\.at',
	`return@mandriva\.com',
	`mailelk@.*swr3\.de',
	`shockwave\.com',
	`RealNetworks',
	`email@softwarewelt\.de',
	`noreply@widget-service\.de',
	`tomtomnews@tomtommailer\.com',
	`promotion5@amazon\.de',
	`mailings@gmx-gmbh\.de',
	`linuxland\.de',
	`macromedia',
	`promotion',
	`<info@cr-elektronik\.de>',
	`office@wenigzell\.at',
	`<annonce@amazon\.fr>',
	`<flashnews@foxfilm\.at>',
	`@news\.niedermeyer\.at>',
	`softwarewelt')`)')

dnl Personal mailboxes

define(`mymbox', `md(`$1', `TO_'q(`$2'))')

mymbox(`INBOX', `ge@gabrielebner.at')
mymbox(`webmaster', `webmaster@gabrielebner.at')
mymbox(`a1net', `dieschnecke@a1.net')